Restating Windows server processes

jwitkow1

Anyone done an APM they could share to restart a process?

JWERLEIN

I am new to Orion.. BUT... They guy before wrote a script that basically looks for a file status and does "stuff" and eventually if the service is in need it restarts it.. (down at the bottom) good luck.. This is copied from the template that it resides in.

===============

' Description:   

'           OldestFileInMinutes.vbs  Reports age of oldest file in    minutes from

'           the folder path provided.

'

'           If file count greater than zero

'                       Check service status

'                       If NOT running

'                                   Start service

'                       fi

'           fi

'

'           Wait 20"

'

'           If file count greater than zero

'                       Restart service (i.e. stop,start)

'           fi

'

'           Wait 10"

'

'           Return file count

'

' Arguments:     computerName, folderPath

'

' Returns:          Integer

'

' Revision History:

' Date        Name                      Description

' ==========  ==========           ===========

' 11/23/2009  JSanborn            Coding modified from scripts by DWeiss

' 01/21/2010  gbutler                Coding modified from scripts by JSanborn

'============================================================================

' Copyright 2009  Ashley Furniture Industries, Inc.

' All Rights Reserved.

'============================================================================

Dim listArguments   'Argument List

Dim oFileSys                'FSO Object

Dim oFolder                 'Holds folder object

Dim strFolderName, strServer

Dim argCount

Dim iNumOldFiles, iMinutes, iUpdatedNumOldFiles

 

On Error Resume Next

 

iNumOldFiles = 0

iUpdatedOldFiles = 0

 

' Orion exit codes - SUCCESS/FAIL

' Only search for File's with extension equal to EXT

Const SUCCESS = 0, FAIL = 1, EXT = "PO"

 

Set listArguments = WScript.Arguments

 

'If not all arguments are passed, then echo the parameters and quit.

If listArguments.Count <> 6 Then

            WScript.Echo "Message: wscript.exe " & WScript.ScriptName & vbCRLF _

            & "-folderPath <The complete file path of the folder you wish to check>" _

            & "-Time <Minutes>"  & vbCRLF _

            & "-Server <Server IP address>"

            WScript.Echo "Statistic: 0"

            WScript.Quit( FAIL )

End If

 

 

For argCount = 0 to listArguments.Length - 1

            If Ucase(listArguments(argCount)) = "-FOLDERPATH" Then

                        strFolderName = listArguments(argCount + 1)

                        argCount = argCount + 1

            ElseIf Ucase(listArguments(argCount)) = "-TIME" Then

                        iMinutes = listArguments(argCount + 1)

                        argCount = argCount + 1

            ElseIf Ucase(listArguments(argCount)) = "-SERVER" Then

                        strServer = listArguments(argCount + 1)

                        argCount = argCount + 1

            Else

                        WScript.Echo "Message: wscript.exe " & WScript.ScriptName & vbCRLF _

                        & "-folderPath <The complete file path of the folder you wish to check>" _

                        & "-Server <Server IP address>" _

                        & "-Time <Minutes>"

                        WScript.Echo "Statistic: 0"

                        WScript.Quit( FAIL )

            End if

Next     

  

  

Set oFileSys = CreateObject("Scripting.FileSystemObject")

Set oFolder = oFileSys.GetFolder(strFolderName)

  

iNumOldFiles = FindOldFiles(oFolder, cInt(iMinutes))

 

' If number of file gt zero and service is down restart service

If ( iNumOldFiles > 0 ) Then

            If ( POAckServiceState(strServer) <> "RUNNING" ) Then

                        Call POAckService(strServer, "StartService")

                        ' Sleep 10 minutes

                        WScript.Sleep(1000 * 60 * 10)

                        iUpdatedNumOldFiles = FindOldFiles(oFolder, cInt(iMinutes))

                        If ( iUpdatedNumOldFiles > 0 ) Then

                                    WScript.Echo "Message:  Found " & iUpdatedNumOldFiles & " files with extension '" & EXT & "' older then " & iMinutes & " minutes."

                                    WScript.Echo "Statistic: " & iUpdatedNumOldFiles

                                    WScript.Quit(SUCCESS)

                        End If   ' iUpdatedNumOldFiles gt zero

            Else 'Service is RUNNING lets wait 20 minutes, and check again

                        ' Sleep 20

                        WScript.Sleep(1000 * 60 * 20)

                        iUpdatedNumOldFiles = FindOldFiles(oFolder, cInt(iMinutes))

                        If ( iUpdatedNumOldFiles >= iNumOldFiles  ) Then

                                    Call POAckService(strServer, "StopService")

                                    ' Write Windows Event stating POAck was restarted by Orion

                                    ' Sleep 2

                                    WScript.Sleep(1000 * 60 * 2)

                                    Call POAckService(strServer, "StartService")

                                    ' Sleep 10

                                    WScript.Sleep(1000 * 60 * 10)

                                    iUpdatedNumOldFiles = FindOldFiles(oFolder, cInt(iMinutes))

                                    If ( iUpdatedNumOldFiles > 0 ) Then

                                                WScript.Echo "Message:  Found " & iUpdatedNumOldFiles & " files with extension '" & EXT & "' older then " & iMinutes & " minutes."

                                                WScript.Echo "Statistic: " & iUpdatedNumOldFiles

                                                WScript.Quit(SUCCESS)

                                    End If

                        End If ' iUpdatedOldFiles gt iNumOldFiles

            End If ' POAck Service Not Running

End If ' Num files gt zero

 

'Cleanup

  

iNumOldFiles = FindOldFiles(oFolder, cInt(iMinutes))

 

WScript.Echo "Message:  Found " & iNumOldFiles & " files with extension '" & EXT & "' older then " & iMinutes & " minutes."

WScript.Echo "Statistic: " & iNumOldFiles

WScript.Quit(SUCCESS)

 

'======================================

'Function Name: FindOldFiles

'Author: Dustin Weiss

'Details: Returns a boolean value based on

'                         finding a file that exceeds the

'                         defined time period and is

'         within the directory specified

'Parameters: objFolder - A specific folder

'                            object to search;

'                                   iMin - number of minutes

' - gpb - Changed to report age of oldest file in minutes

' - gpb - Changed to only look at files with the extension = EXT

' - gpb - Changed to report the number of files with age > iMinutes

'======================================

Function FindOldFiles(objFolder, iMinThreshold)

            Dim oFiles

            Dim oFile

            Dim aModDate

            Dim bModDate

            Dim iTimeDiff

            Dim sFileName

            Dim iIndex, iCount

 

            On Error Resume Next

 

   iCount = 0

           

   Set oFiles = objFolder.Files

   bModDate = Now()

  

   For Each oFile In oFiles 'Iterates through all files in the dir

            sFileName = oFile.Name

            iIndex = InStr(sFileName, ".")

            If Ucase(Mid(sFileName, iIndex + 1)) = EXT Then

                        aModDate = oFile.DateLastModified 'Get last modified date for each file

            iTimeDiff = DateDiff("n", aModDate, bModDate)

            If ( iTimeDiff > iMinThreshold )  Then  'If the current file date is older

                        iCount = iCount + 1

                                    'wscript.echo "File: " & oFile.Name & " Time difference: " & iTimeDiff & "; Threshold: " & iMinThreshold & " Counter: " & iCount

            End If

        End If

   Next

   

   'WScript.Echo  "Oldest file: " & bModDate

 

   'tDiff = DateDiff("n", bModDate, Now()) 'Compares the oldest date to now

 

   'Wscript.echo tDiff & " = Time Difference "

  

   'Cleanup.

   set oFile = Nothing

   set oFiles = Nothing

  

   FindOldFiles = iCount

  

End Function

 

'======================================

'Function Name: POAckService Status

'Author: Glenn Butler

'Details: Report POAckService Status

'Parameters: InputString, Server Name

'======================================

Function POAckServiceState(sServer)

            Dim strComputer, objWMIService, colItems, objItem, strState

            On Error Resume Next

            strState = " "

            strComputer = sServer

            Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")

            Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Service WHERE Name = 'Acknowledgement Import'",,48)

            CALL ErrorCheck(Err.Number, "objWMIService.ExecQuery")

 

            For Each objItem In colItems

                        strState = Ucase(objItem.State)

            Next

 

            POAckServiceState = strState

End Function

 

'======================================

'Function Name: POAckService

'Author: Glenn Butler

'Details: Start/Stops POAckService

'Parameters: InputString, Server Name

'======================================

Function POAckService(sServer, sCmd)

            Dim strComputer, objWMIService,  objItem, objOutParams

            On Error Resume Next

            strComputer = sServer

            Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")

            Set objOutParams = objWMIService.ExecMethod("Win32_Service.DisplayName='Acknowledgement Import'", sCmd)

            CALL ErrorCheck(Err.Number, "objWMIService.ExecMethod")

 

End Function

 

'======================================

'Function Name: ErrorCheck

'Author: Glenn Butler

'Details: Write data to log file

'Parameters: InputString

'======================================

Function ErrorCheck(ReturnCode, sdata)

            Dim strMesg

            If ReturnCode <> 0 then

                        strMesg =  "Error " & ReturnCode & " occured from the " & sdata & " command."

                        WScript.Echo "Message: Failure " & strMesg

                        WScript.Quit(FAIL)

            End If

End Function