Windows Script Monitor output message incomplete

Bad_Bulldog

Hello,

I recently wrote a script that checks every five minutes the windows event logs for the presence of a specific event. The script works flawlessly except that where I use the WScript.Echo "Message: " output method, it only throws back the first line of the message content. The variable thrown to the output contains the whole message of the event. When I run the script in a command prompt I get the whole message. It seems as though APM ignores all but the first lines of the message.

Any ideas?

Bad_Bulldog

Hello,

I finally ffixed my statistical problem and my message output problem. The statistical info was not outputted because I exited the script with a WScript.Quit(FAILURE) instead of WScript.Quit(SUCCESS). For the message output, linefeeds in the message body was preventing the whole message to be displayed.

Here is my final script:

'=============================================
'  Script:  WMI_NTEVENTLOG.vbs
'  Auteur:  Pierre-Emmanuel Turcotte
'  Org.:  CHUQ
'  Date:  2009/04/16
'=============================================

OPTION EXPLICIT

CONST SUCCESS = 0
CONST FAILURE = 1

DIM lstArguments
DIM strComputer
DIM intEventID
DIM strSource
DIM strLogFile
DIM objWMIService
DIM objWMINTEventLog
DIM objWMILogElement
DIM objWMIDateTimeMinus
DIM dateTimeMinus
DIM intLogCount
DIM strLogMessageBlock
DIM arrayLogMessage
DIM intArrayLine

SET lstArguments = WScript.Arguments

IF lstArguments.Count = 4 THEN
 strComputer = TRIM(lstArguments(0))
 strLogFile = TRIM(lstArguments(1))
 strSource =  TRIM(lstArguments(2))
 intEventID = TRIM(lstArguments(3))
' WScript.Echo "Message: ARGUMENTS OK :: " & strComputer & " " & strLogFile & " " & strSource & " " & intEventID
ELSE
 WScript.Echo "Message: INVALID PARAMETERS :: SCRIPT.VBS [COMPUTER] [LOGFILE] [SOURCE] [EVENTID]"
 WScript.Echo "Statistic: " & 0
 WScript.Quit(FAILURE)
END IF

dateTimeMinus = DateAdd("n", -5, Now)

SET objWMIDateTimeMinus = CreateObject("WbemScripting.SWbemDateTime")
objWMIDateTimeMinus.SetVarDate(dateTimeMinus)

SET objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\CIMV2")

IF (IsEmpty(objWMIService) = TRUE) THEN
 WScript.Echo "Message: WMI NOT INITIALIZED :: [COMPUTER]"
 WScript.Quit(FAILURE)
'ELSE
' WScript.Echo "Message: WMI OBJECT OK"
END IF

SET objWMINTEventLog = objWMIService.ExecQuery("SELECT * FROM Win32_NTLogEvent WHERE LogFile='" & strLogFile & "' AND SourceName='" & strSource & "' AND EventCode='" & intEventID & "' AND TimeGenerated >='" & objWMIDateTimeMinus & "'")

IF (IsEmpty(objWMINTEventLog) = TRUE) THEN
 WScript.Echo "Message: WMI Win32_NTLogEvent NOT INITIALIZED :: [COMPUTER]"
 WScript.Quit(FAILURE)
'ELSE
' WScript.Echo "Message: WMI OBJECT OK"
END IF

intLogCount = objWMINTEventLog.Count

IF intLogCount = 0 Then
 WScript.Echo "Message: No Events Found"
 WScript.Echo "Statistic:0"
 WScript.Quit(SUCCESS)
ELSE
 FOR EACH objWMILogElement IN objWMINTEventLog
  strLogMessageBlock = objWMILogElement.Message
  strLogMessageBlock = Replace(strLogMessageBlock,CHR(10)," - ")
  strLogMessageBlock = Replace(strLogMessageBlock,CHR(09),"")
  EXIT FOR
 NEXT
 WScript.Echo "Statistic:" & CStr(intLogCount)
 WScript.Echo "Message: " & intLogCount & " Events found. Description of the last event found: " & strLogMessageBlock
 WScript.Quit(SUCCESS)
END IF