HTTP component monitor in APM that uses returned value as Statistic?

KenKasmar

In trying to leverage APM to collect statistics from actual applications in our environment I need to have an APM component hit a URL via HTTP and use the value returned by the application as the statistic (rather than just verifying the contents and returning the response time).  Is this possible with any out of the box APM component types or am I going to need to do the old 'script monitor that runs a script that does a curl or such, parses the data returned and returns the value' path?

Example:

If it hit a URI string for a server:port that an application listening on like

server:12345/.../HttpHandlerService

that service returns '325' (which would be the statistic that I want to capture for this polling cycle).

romkon

No out of box APM component does that.

I have created vbscript for you.

It has not been fully tested and is far from being perfect but it does the job (providing that those requested pages don't return html but simple text).

'---------------------------------------------------------------

args = WScript.Arguments.Count

if args <> 1 then
  Wscript.Echo "usage: GetPage.vbs URL"
  wscript.Quit
end if

URL = WScript.Arguments.Item(0)

Set WshShell = WScript.CreateObject("WScript.Shell")

Set http = CreateObject("Microsoft.XmlHttp")

on error resume next

http.open "GET", URL, FALSE
if err <> 0 then  ExitWithError "Page " & URL & " can't be opened"

http.send ""
if err <> 0 then  ExitWithError "Page " & URL & " can't be sent"

on error goto 0

if http.status <> 200 then ExitWithError "Requesting page " & URL & " returned error status: " & http.statusText

ExitWithSucess "Page " & URL & " processed sucesfully", http.responseText

sub ExitWithError(message)
 WScript.Echo "Message: - " & message
 WScript.Echo "Statistic: 0"
    WScript.Quit( 1 )
end sub

sub ExitWithSucess(message, statistics)
 WScript.Echo "Message: - " & message
 WScript.Echo "Statistic: " & statistics
    WScript.Quit( 0 )
end sub